- En utilisant la syntaxe CFML :
<cfoutput>     <cfloop from="1" to="5" index="indexItem" step="1">         L'indice de la boucle est : #indexItem#<BR />     </cfloop> </cfoutput>

Attribut	Requis	Description
from		Valeur de début pour l'indice de la boucle.
to		Valeur de fin pour l'indice de la boucle.
index		Nom de la variable qui va correspondre à l'indice de la boucle.
step		(valeur par défaut : 1) Valeur pour incrémenter/décrémenter l'indice de la boucle à chaque itération.

- En utilisant le tag CFScript :
<cfscript>     for (indexItem = 1; indexItem <= 5; indexItem++) {         writeOutput("L'indice de la boucle est : " & indexItem & "<BR />");     } </cfscript>
Note de performance (1) : Les boucles avec le tag cfloop sont moins rapides que les boucles dans CFScript. Voici le code Java généré par ColdFusion pour les deux cas :

- Le tag cfloop est traduit en :
double t8 = 1.0D; double t10 = Cast._double("5"); double t12 = Cast._double("1"); Object value = Cast._Object(t12); Variable t14 = bindPageVariable("INDEXITEM", null); t14.set(value); for( ; CfJspPage._checkCondition(t8,t12,t10) ; CfJspPage.checkRequestTimeout("cfloop") ) { out.write("\r\n        <BR />L'indice de la boucle est : "); out.write(Cast._String(_autoscalarize(INDEXITEM))); out.write(".\r\n    "); value = Cast._Object(t12 += t8); t14.set(value); }
- La boucle dans le tag CFScript ColdFusion est traduite en :
INDEXITEM.set("1"); for( ; CfJspPage._compare(_autoscalarize(INDEXITEM), 5D) <= 0.0D ; INDEXITEM.set(Cast._Object(Cast._double(_autoscalarize(INDEXITEM)) + 1.0D)) ) { WriteOutput("<BR />L'indice de la boucle est : ".concat(Cast._String(_autoscalarize(INDEXITEM)))); }
Le code Java du tag CFScript est clairement plus simple. Tous les détails ajoutés pour le tag cfloop sont la cause de différence de performance qu'on peut facilement tester si les boucles sont longues.

Note de performance (2) : ColdFusion peut insérer un saut de ligne ou une ligne vide pour chaque saut de ligne entre les tags CFML. Dans l'exemple précédent, il y aura des sauts de lignes dans la page HTML pour chaque itération de la boucle cfloop. L'ajout de ces lignes peut "affecter" les performances de la page, ce qui est normal puisque ColdFusion ajoute du code pour écrire ces lignes vides en plus la taille de la page HTML devient plus grande avec l'ajout de ces lignes vides. Vous pouvez éviter l'ajout de ces sauts de lignes si :
- vous enleviez les espaces entre les tags !
- vous utilisiez la fonction « WriteOutput » !
- sinon, vous pouvez utiliser le tag « cfprocessingdirective » qui permet d'éliminer les lignes vides (j'ai essayé de le tester mais ca n'a pas fonctionner !).

Exemple :
<cfsetting showdebugoutput="no"> <cfoutput> Première boucle :<BR /> <cfloop from="1" to="3" index="indexItem"> L'indice de la boucle est : #indexItem#<BR /> </cfloop> <BR />Deuxième boucle : <cfloop from="1" to="3" index="indexItem"> <BR />L'indice de la boucle est : #indexItem# </cfloop> <BR /><BR />Troisième boucle :<BR /> <cfloop from="1" to="3" index="indexItem">L'indice de la boucle est : #indexItem#<BR /></cfloop> </cfoutput>
Voici le résultat affiché dans le navigateur :
Première boucle : L'indice de la boucle est : 1 L'indice de la boucle est : 2 L'indice de la boucle est : 3 Deuxième boucle : L'indice de la boucle est : 1 L'indice de la boucle est : 2 L'indice de la boucle est : 3 Troisième boucle : L'indice de la boucle est : 1 L'indice de la boucle est : 2 L'indice de la boucle est : 3
Voici le code html généré :
Ligne  1: Ligne  2:Première boucle :<BR />    Ligne  3: Ligne  4:L'indice de la boucle est : 1<BR /> Ligne  5: Ligne  6:L'indice de la boucle est : 2<BR /> Ligne  7: Ligne  8:L'indice de la boucle est : 3<BR /> Ligne  9: Ligne 10:<BR />Deuxième boucle : Ligne 11: Ligne 12:<BR />L'indice de la boucle est : 1 Ligne 13:<BR />L'indice de la boucle est : 2 Ligne 14:<BR />L'indice de la boucle est : 3 Ligne 15:<BR /><BR />Troisième boucle :<BR /> Ligne 16:L'indice de la boucle est : 1<BR />L'indice de la boucle est : 2<BR />L'indice de la boucle est : 3<BR />
Remarques :
- Pour la première boucle, il y a un saut de ligne et une ligne vide pour chaque itération.
- Pour la deuxième boucle, il y a juste un saut de ligne pour chaque itération.
- Pour la troisième boucle, il n'y a aucun saut de ligne.

TODO : Ajouter des détails sur CfJspPage.checkRequestTimeout("cfloop")

- En utilisant la syntaxe CFML :
<cfoutput> <cfset indexItem=1>     <cfloop condition="indexItem LTE 5">         L'indice de la boucle est : #indexItem#<BR />         <cfset indexItem+=1>     </cfloop> </cfoutput>

Attribut	Requis	Description
condition		Condition pour contrôler la continuité de la boucle (évaluer à chaque itération).

- En utilisant le tag CFScript : while
<cfscript>     indexItem = 1;     while (indexItem <= 5) {         writeOutput("L'indice de la boucle est : " & indexItem & "<BR />");         indexItem+=1;     } </cfscript>
- En utilisant le tag CFScript : do while
<cfscript>     indexItem = 1;     do {         writeOutput("L'indice de la boucle est : " & indexItem & "<BR />");         indexItem+=1;     } while (indexItem <= 5); </cfscript>
- En utilisant le tag CFScript : for
<cfscript>     indexItem = 1;     for (;indexItem <= 5;) {         writeOutput("L'indice de la boucle est : " & indexItem & "<BR />");         indexItem++;     } </cfscript>

- En utilisant la syntaxe CFML :
<cfoutput>     <cfloop array="#["A","B","C","D","E"]#" index="arrayItem">         L'élément du tableau est : #arrayItem#<BR />     </cfloop> </cfoutput>

Attribut	Requis	Description
array		Tableau.
index		Nom de la variable qui va correspondre aux éléments du tableau.

- En utilisant la syntaxe CFML :
<cfoutput> <cfset myArray = ["A","B","C","D","E"]>     <cfloop from="1" to="#ArrayLen(myArray)#" index="indexItem">         L'élément du tableau est : #myArray[indexItem]#<BR />     </cfloop> </cfoutput>
- En utilisant le tag CFScript : for
<cfscript>     myArray = ["A","B","C","D","E"];     for (indexItem=1;indexItem <= ArrayLen(myArray);indexItem++) {         writeOutput("L'élément du tableau est : " & myArray[indexItem] & "<BR />");     } </cfscript>

- En utilisant la syntaxe CFML :
<cfoutput> <cfset myStruct = {item1="A",item2="B",item3="C",item4="D",item5="E"} /> <cfloop collection="#myStruct#" item="keyName"> L'élément de la structure [#keyName#] est : #myStruct[keyName]# <BR /> </cfloop> </cfoutput>

Attribut	Requis	Description
collection		Structure.
item		Nom de la variable qui va correspondre aux clés de la structure.

- En utilisant le tag CFScript : for in
<cfscript> myStruct = {item1="A",item2="B",item3="C",item4="D",item5="E"}; for (keyName in myStruct) { writeOutput("L'élément de la structure [" & keyName & "] est : " & myStruct[keyName] & "<BR />"); } </cfscript>

- En utilisant la syntaxe CFML :
<cfoutput> <cfloop list="A,B,C" index="listItem" delimiters=","> L'élément de la liste est : #listItem# <BR /> </cfloop> </cfoutput>

Attribut	Requis	Description
list		Liste.
index		Nom de la variable qui va correspondre aux éléments de la liste.
delimiters		(valeur par défaut : ,) Séparateur des éléments de la liste. Il est possible de spécifier plusieurs séparateurs.

- En utilisant la syntaxe CFML :
<cfoutput>     <cfloop from="#Now()#" to="#Now()+5#" index="indexItem" step="1">         L'indice de la boucle est : #dateformat(indexItem, "mm/dd/yyyy")#<BR />     </cfloop> </cfoutput>
<cfoutput> <cfloop from="#CreateTime(0,0,0)#" to="#CreateTime(5,0,0)#" index="indexItem" step="#CreateTimeSpan(0,0,30,0)#"> L'indice de la boucle est : #timeFormat(indexItem, "HH:MM:SS")#<BR /> </cfloop> </cfoutput>

Attribut	Requis	Description
from		Valeur de début pour l'indice de la boucle.
to		Valeur de fin pour l'indice de la boucle.
index		Nom de la variable qui va correspondre à l'indice de la boucle.
step		(valeur par défaut : 1 Jour) Valeur pour incrémenter/décrémenter l'indice de la boucle à chaque itération.

- En utilisant la syntaxe CFML :
<cfset myQuery = QueryNew("ID, CODE", "Integer, VarChar")> <cfset newRow = QueryAddRow(myQuery, 4)> <cfset temp = QuerySetCell(myQuery, "ID", "111", 1) /> <cfset temp = QuerySetCell(myQuery, "CODE", "A", 1) /> <cfset temp = QuerySetCell(myQuery, "ID", "222", 2) /> <cfset temp = QuerySetCell(myQuery, "CODE", "B", 2) /> <cfset temp = QuerySetCell(myQuery, "ID", "333", 3) /> <cfset temp = QuerySetCell(myQuery, "CODE", "C", 3) /> <cfset temp = QuerySetCell(myQuery, "ID", "444", 4) /> <cfset temp = QuerySetCell(myQuery, "CODE", "D", 4) /> <cfoutput> <cfloop query="myQuery" startRow="2" endRow="3"> #myQuery.currentRow# : ID : #myQuery.ID# | CODE : #myQuery.CODE#<br/> </cfloop> </cfoutput>

Attribut	Requis	Description
query		Nom de la variable de l'objet requête.
startRow		Numéro de ligne de l'objet requête, à utiliser comme début de la boucle.
endRow		Numéro de ligne de l'objet requête, à utiliser pour arrêter la boucle.

Remarque : La variable « currentRow » est une variable initialisée par ColdFusion qui donne le numéro de la ligne de l'objet requête à l'itération courante.

- En utilisant la syntaxe CFML :
<cfoutput> <cfloop file="C:\notes.txt" index="fileLine" characters="10"> Ligne du fichier : #fileLine#<br /> </cfloop> </cfoutput>

Attribut	Requis	Description
file		Nom et chemin du fichier.
index		Nom de la variable qui va correspondre aux lignes lues du fichier.
characters		Nombre de caractères à lire du fichier à chaque itération de la boucle.

Le tag CFBREAK arrête l'exécution de la boucle alors que le tag CFCONTINUE arrête l'exécution du code de la boucle pour l'itération en cours et saute à la prochaine itération de la boucle.

- En utilisant la syntaxe CFML :
<cfoutput>     <cfloop from="1" to="5" index="indexItem" step="1"> <cfif indexItem mod 2 EQ 0> <cfcontinue /> <cfelseif indexItem GT 4> <cfbreak /> </cfif> L'indice de la boucle est : #indexItem#<BR />     </cfloop> </cfoutput>
Voici le résultat affiché dans le navigateur :
L'indice de la boucle est : 1 L'indice de la boucle est : 3
- En utilisant le tag CFScript :
<cfscript>     for (indexItem = 1; indexItem <= 5; indexItem++) { if(indexItem mod 2 EQ 1) continue; else if(indexItem GT 4) break; writeOutput("L'indice de la boucle est : " & indexItem & "<BR />");     } </cfscript>
Voici le résultat affiché dans le navigateur :
L'indice de la boucle est : 2 L'indice de la boucle est : 4